Tutorial for converting maps from MP3 to MP4

[BestNoob]

Does anyone have the old setup from 2017 ?
With an old Setup it should work or not ( offline mode) ?

[stefan.fueger]

OK, does anybody have an idea how to convert maps from MP3 to MP4.1 ... the described methods do not work anymore.

[eyebo]

Hmm whatever i try i do not get it to work. I hope that you can help me.
It definily doesnt work with MP4

OK, does anybody have an idea how to convert maps from MP3 to MP4.1 ... the described methods do not work anymore.

Yes, batch computing is currently broken.

It's a known issue though. The next update will fix it.
So just hang on a little while and you'll be able to do it again using the tutorials in this topic.

[BestNoob]

@nadeo great that you fixed it =)

But there are still a few questions:

Why is my GPU usage not at 100% for, cumputing maps, calculating shadows only the processor is used ?

Why got the maps not sorted by Title ?

Why arent all maps recognized correctly ? There some maps not recognized by the game and convert option ?

Why is there no ingame or automated option for this procedure ?

Are this the correct usable options ?
/LmQuality=Low
/LmQuality=Fast
/LmQuality=Default
/LmQuality=High
/LmQuality=Ultra

What happen if i doesnt use this commands ?
/useronly
/fullcheck
/LmQuality=

Whats up with the stuff in LightmapsCopy folder ? Delete or keep ? Like that:
0BB00C62450835C671C2499D12B1C03F615E4AF115417D11F9BFB43A78A06CDE_B96165B311A00466_Canyon_Day.Bump.LightMap.zip

Does index script still work correctly ?
viewtopic.php?f=265&t=41705&p=286485&hi ... ty#p286485

How to use it?

• Create a text file in your maniaplanet directory (where Maniaplanet.exe resides)

• copy the following code and paste it in the new text file

• save the text file as "converter.cmd" with quotation marks!

• create a shortcut to the text file on your desktop for easy access

Have fun!

Code: Select all

@echo off
rem **********************************************************************
rem *                                                                    *
rem * Upgrade and/or recalculate the shadows of your maps                *
rem *                                                                    *
rem * v0.1.2017-06-02                                                    *
rem *                                                                    *
rem **********************************************************************

:START
	set QUALITY=
	set TITLES=
	set MAPTYPE=
	set UPGRADE=

:SELECTQUALITY
	cls

	echo Maniaplanet - Convert maps
	echo.
	echo Select Quality
	echo.
	echo (1) Ultra
	echo (2) High
	echo (3) Default
	echo (4) Fast
	echo.
	set /p _QUALITY="Select Quality: "
	if /i "%_QUALITY%"=="1" set QUALITY=/LmQuality=Ultra
	if /i "%_QUALITY%"=="2" set QUALITY=/LmQuality=High
	if /i "%_QUALITY%"=="3" set QUALITY=/LmQuality=Default
	if /i "%_QUALITY%"=="4" set QUALITY=/LmQuality=Fast

:SELECTENVIRONMENT
	cls

	echo Maniaplanet - Convert maps
	echo.
	echo Select Title(s)
	echo.
	echo (1) Canyon  (only)
	echo (2) Valley  (only)
	echo (3) Lagoon  (only)
	echo (4) Stadium (only)
	echo (5) Storm   (only)
	echo.
	echo (6) All titles
	echo.
	echo Current choices:
	echo QUALITY: %QUALITY%
	echo.
	set /p _TITLES="Select Environment: "
	if /i "%_TITLES%"=="1" set TITLES=/titles=TMCanyon
	if /i "%_TITLES%"=="2" set TITLES=/titles=TMValley
	if /i "%_TITLES%"=="3" set TITLES=/titles=TMLagoon
	if /i "%_TITLES%"=="4" set TITLES=/titles=TMStadium
	if /i "%_TITLES%"=="5" set TITLES=/titles=SMStorm
	if /i "%_TITLES%"=="6" set TITLES=

:SELECTMAPTYPE
	cls

	echo Maniaplanet - Convert maps
	echo.
	echo Select Maptype to convert
	echo.
	echo (1) User maps only
	echo (2) All maps (including official maps)
	echo.
	echo Current choices:
	echo QUALITY: %QUALITY%
	echo TITLES:  %TITLES%
	echo.
	set /p _MAPTYPE="Select maptype: "
	if /i "%_MAPTYPE%"=="1" set MAPTYPE=/useronly
	if /i "%_MAPTYPE%"=="2" set MAPTYPE=

:SELECTUPGRADE
	cls

	echo Maniaplanet - Convert maps
	echo.
	echo Do you want to upgrade maps
	echo.
	echo (1) Enable upgrade
	echo (2) Disable upgrade
	echo.
	echo Current choices:
	echo QUALITY: %QUALITY%
	echo TITLES:  %TITLES%
	echo MAPTYPE: %MAPTYPE%
	echo.
	set /p _UPGRADE="Select maptype: "
	if /i "%_UPGRADE%"=="1" set UPGRADE=/upgrademaps
	if /i "%_UPGRADE%"=="2" set UPGRADE=

:LASTCHOICE
	cls
	color 0c

	echo Maniaplanet - Convert maps
	echo.
	echo Start conversion or restart this script
	echo.
	echo (1) Start conversion
	echo (2) Restart this script (including official maps)
	echo.
	echo Current choices:
	echo QUALITY: %QUALITY%
	echo TITLES:  %TITLES%
	echo MAPTYPE: %MAPTYPE%
	echo UPGRADE: %UPGRADE%
	echo.
	echo Command line: ManiaPlanet.exe /computeallshadows %UPGRADE% %MAPTYPE% /fullcheck %QUALITY% %TITLES%
	echo.
	set /p _EXECUTE="Start conversion or restart this script: "
	if /i "%_EXECUTE%"=="1" goto STARTCONVERSION
	if /i "%_EXECUTE%"=="2" goto START

:STARTCONVERSION
	@echo off
	ManiaPlanet.exe /computeallshadows %UPGRADE% %MAPTYPE% /fullcheck %QUALITY% %TITLES%
	pause

[Miss]

Does index script still work correctly ?
viewtopic.php?f=265&t=41705&p=286485&hi ... ty#p286485

Have you tried?